#!/bin/csh -f

# Please change the following line to reflect your own setup

setenv DSS_ROOT  /your/path   # <<<=== the directory that contains the following: bin.hp  bin.lin86  bin.macosx  bin.sun4s  dino.jpg  headers  INSTALL  README.html  scripts


#
# Do not change anything below
#

if ( $1 == "" || $1 == "-h" || $1 == "--help") then
    echo "Usage: $0 { red | blue | IR } [-i input_file]"
    exit
endif

set color=$1
shift

# Use DSS_HOST if the data files are to be retrieved via http
setenv DSS_HOST "archive.eso.org"
setenv DSS_PORT "80"

# Use DSS_LOG if logging function should be switched on
setenv DSS_LOG "http://archive.eso.org/cgi-bin/dsslog"

# mount point for the data CD's or disks
# must  correspond to doc root of the http server
setenv DSS_MTPT "/dss2/" 

# Directory with header files   
setenv DSS_HDRS  $DSS_ROOT/headers

# Header file extension
setenv DSS_EXTN hhh

# Plate list file
switch ( $color )
case red:
    setenv DSS_PLTL xdssdvd_r.lis
    setenv DSS_CLIENT "dss-2.56dr"
    breaksw
case blue:
    setenv DSS_PLTL xdssdvd_b.lis
    setenv DSS_CLIENT "dss-2.56db"
    breaksw
case IR:
    setenv DSS_PLTL xdssdvd_i.lis
    setenv DSS_CLIENT "dss-2.56di"
    breaksw
default:
    echo "Usage: dss2{ red | blue | IR } [-i input_file]"
    exit
endsw

# Prefix for CD-ROM disc volume labels    
setenv DSS_LBPF usa_aura_stsi_xdss

# Do not change any of the one below
setenv DSS_MNT  "cd"
setenv DSS_DMNT ""
setenv DSS_DEV  ""

# Execute th actual getimage program

switch ( "`uname -rms`" )
    case HP-UX*:
        setenv ARCH hp
        breaksw
    case SunOS*5.*:
        setenv ARCH sun4s
        breaksw
    case Linux*86*:
        setenv ARCH lin86
        breaksw
    case Darwin*:
        setenv ARCH macosx
        breaksw
    default:
        setenv ARCH unknown
        echo "Error - unrecognized computer platform"
        breaksw
endsw

$DSS_ROOT/bin.$ARCH/dss $*